cmake_minimum_required(VERSION 3.6)

project(SnakeGame CXX)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

set(SDLIMAGE_AVIF OFF CACHE BOOL "" FORCE)
set(SDLIMAGE_AVIF_SHARED OFF CACHE BOOL "" FORCE)
set(SDLIMAGE_AVIF_STATIC OFF CACHE BOOL "" FORCE)

set(JNI_DIR "${CMAKE_SOURCE_DIR}/android-project/app/jni")
add_subdirectory("${JNI_DIR}")

add_executable(${PROJECT_NAME}
    "${JNI_DIR}/src/Snake.cpp"
    "${JNI_DIR}/src/Snake/Snake.h"
    "${JNI_DIR}/src/Snake/Snake.cpp"
)

target_include_directories(${PROJECT_NAME} PRIVATE
    "${JNI_DIR}/src"
    "${JNI_DIR}/SDL/include"
    "${JNI_DIR}/SDL_image/include"
    "${JNI_DIR}/SDL_ttf/include"
    "${JNI_DIR}/SDL_mixer/include"
)

if(NOT TARGET SDL3::SDL3)
    find_package(SDL3 CONFIG REQUIRED)
endif()
if(NOT TARGET SDL3_image::SDL3_image)
    find_package(SDL3_image CONFIG REQUIRED)
endif()
if(NOT TARGET SDL3_ttf::SDL3_ttf)
    find_package(SDL3_ttf CONFIG REQUIRED)
endif()
if(NOT TARGET SDL3_mixer::SDL3_mixer)
    find_package(SDL3_mixer CONFIG REQUIRED)
endif()

target_link_libraries(${PROJECT_NAME} PRIVATE SDL3::SDL3 SDL3_image::SDL3_image SDL3_ttf::SDL3_ttf SDL3_mixer::SDL3_mixer)

add_custom_command(TARGET ${PROJECT_NAME}
	POST_BUILD
	COMMAND "${PROJECT_SOURCE_DIR}/android-project/install.bat"
	COMMAND ${CMAKE_COMMAND} -E copy "${PROJECT_SOURCE_DIR}/android-project/app/src/main/assets/allerrg.ttf" "${PROJECT_BINARY_DIR}/allerrg.ttf"
)